Funciones CONTAR.SI y SUMAR.SI
- =CONTAR.SI(¿Dónde quiere realizar la búsqueda y qué quiere buscar?)
Por ejemplo:
- =CONTAR.SI(A2:A5;”Londres”)
- =CONTAR.SI(A2:A5;A4)
Ejemplos
Para usar estos ejemplos de Excel, copie los datos de la tabla de abajo y péguelos en la celda A1 de una nueva hoja de cálculo.
| Datos | Datos |
|---|---|
| manzanas | 32 |
| naranjas | 54 |
| melocotones | 75 |
| manzanas | 86 |
| Fórmula | Descripción |
| =CONTAR.SI(A2:A5;”manzanas”) | Cuenta el número de celdas con manzanas entre las celdas A2 y A5. El resultado es 2. |
| =CONTAR.SI(A2:A5;A4) | Cuenta el número de celdas con melocotones, el valor de A4, entre las celdas A2 y A5. El resultado es 1. |
| =CONTAR.SI(A2:A5;A2)+CONTAR.SI(A2:A5;A3) | Cuenta el número de manzanas, el valor de A2, y de naranjas, el valor de A3, entre las celdas A2 y A5. El resultado es 3. Esta fórmula usa CONTAR.SI dos veces para especificar varios criterios, un criterio por expresión. También puede utilizar la función CONTAR.SI.CONJUNTO. |
| =CONTAR.SI(B2:B5;”>55″) | Cuenta el número de celdas con un valor superior a 55 entre las celdas B2 y B5. El resultado es 2. |
| =CONTAR.SI(B2:B5;”<>”&B4) | Cuenta el número de celdas con un valor distinto de 75 entre las celdas B2 y B5. El símbolo de la “y” (&) combina el operador de comparación “<>” (no es igual a) y el valor de B4 para leer =CONTAR.SI(B2:B5;”<>75″). El resultado es 3. |
| =CONTAR.SI(B2:B5;”>=32″)-CONTAR.SI(B2:B5;”<=85″) | Cuenta el número de celdas con un valor superior o igual a 32 e inferior o igual a 85 entre las celdas B2 y A5. El resultado es 1. |
| =CONTAR.SI(A2:A5;”*”) | Cuenta el número de celdas que contienen texto entre las celdas A2 y A5. El carácter comodín * se usa para reemplazar cualquier carácter. El resultado es 4. |
| =CONTAR.SI(A2:A5;”?????nas”) | Cuenta el número de celdas que tienen exactamente 8 caracteres y que terminan con las letras “nas” entre las celdas A2 y A5. El signo de interrogación (?) se usa como carácter comodín para coincidir con caracteres individuales. El resultado es 2. |
Problemas comunes
| Problema | Qué ha fallado |
|---|---|
| Se devolvió un valor incorrecto para cadenas largas. | La función CONTAR.SI devuelve resultados incorrectos cuando se usa para comparar cadenas de más de 255 caracteres.
Para comparar cadenas de más de 255 caracteres, use la función CONCATENAR o el operador concatenar &. Por ejemplo, =CONTAR.SI(A2:A5;”cadena larga”&”otra cadena larga”). |
| No se devolvió ningún valor cuando se esperaba uno. | Asegúrese de encerrar el argumento de criterios entre comillas. |
| Una formula CONTAR.SI recibe un error #¡VALOR! al hacer referencia a otra hoja de cálculo. | Este error se produce cuando la fórmula que contiene la función hace referencia a celdas o a un rango de un libro cerrado y se calculan las celdas. Para que esta característica funcione, el otro libro debe estar abierto. |
Prácticas recomendadas
| Realice este procedimiento | ¿Por qué? |
|---|---|
| Tenga en cuenta que CONTAR.SI pasa por alto mayúsculas y minúsculas en las cadenas de texto. | Los criterios no distinguen entre mayúsculas y minúsculas. En otras palabras, la cadena “manzanas” y la cadena “MANZANAS” darán como resultado la misma cantidad de celdas. |
| Use caracteres comodín. | Los caracteres comodín, como el signo de interrogación (?) y asterisco (*), pueden usarse en criterios. El signo de interrogación reemplaza cualquier carácter individual. El asterisco reemplaza cualquier secuencia de caracteres. Si lo que desea buscar es un signo de interrogación o un asterisco, escriba una tilde (~) antes del carácter.
Por ejemplo, =CONTAR.SI(A2:A5;”manzana?”) contará todas las instancias de “manzana” con una última letra que podrá variar. |
| Asegúrese de que los datos no contienen caracteres incorrectos. | Al contar valores de texto, asegúrese de que los datos no contienen espacios al principio ni al final, de que no haya un uso incoherente de las comillas rectas (‘ o “) ni tipográficas (‘ o “) y de que no haya caracteres no imprimibles. En estos casos, CONTAR.SI puede devolver un valor inesperado o incorrecto.
Intente usar la función LIMPIAR o la función ESPACIOS. |
| Para mayor comodidad, use rangos con nombre. | CONTAR.SI admite el uso de rangos con nombre en una fórmula (por ejemplo, =CONTAR.SI(fruta;”>=32″)-CONTAR.SI(fruta;”>85″). El rango con nombre puede estar en la hoja de cálculo actual, en otra hoja de cálculo del mismo libro o en una hoja de cálculo de otro libro. Para hacer referencia a otro libro, ese libro también debe estar abierto. |
Sugerencias:
- Si lo desea, puede aplicar los criterios a un rango y sumar los valores correspondientes de otro rango. Por ejemplo, la fórmula =SUMAR.SI(B2:B5;”Juan”;C2:C5) suma solamente los valores del rango C2:C5 en los que las celdas correspondientes del rango B2:B5 sea igual a “Juan”.
- Para sumar las celdas en función de varios criterios, vea la función SUMAR.SI.CONJUNTO.
Importante: La función SUMAR.SI devuelve resultados incorrectos cuando se usa para comparar cadenas de más de 255 caracteres o con la cadena #¡VALOR!.
Sintaxis
SUMAR.SI(rango; criterio; [rango_suma])
La sintaxis de la función SUMAR.SI tiene los argumentos siguientes:
- intervalo Obligatorio. El rango de celdas que se desea evaluar según los criterios. Las celdas de cada rango deben ser números, nombres, matrices o referencias que contengan números. Los valores en blanco y de texto se ignoran. El rango seleccionado puede contener fechas en formato estándar de Excel (a continuación se incluyen ejemplos).
- criterios Obligatorio. Es el criterio en forma de número, expresión, referencia de celda, texto o función que determina las celdas que va a sumar. Se pueden incluir caracteres comodín: un signo de interrogación (?) para que coincida con cualquier carácter individual, un asterisco (*) para que coincida con cualquier secuencia de caracteres. Si desea buscar un signo de interrogación o un asterisco real, escriba una tilde (~) antes del carácter.Por ejemplo, los criterios pueden expresarse como 32, “>32”, B5, “3?”, “manzanas*”, “*~” u HOY().
Importante: Cualquier criterio de texto o cualquier criterio que incluya los símbolos lógicos o matemáticos debe estar entre comillas dobles (“). Si el criterio es numérico, las comillas dobles no son necesarias.
- Rango_suma Opcional. Son las celdas reales que se sumarán, si es que desea sumar celdas a las ya especificadas en el argumento rango. Si omite el argumento rango_suma, Excel suma las celdas especificadas en el argumento rango (las mismas celdas a las que se aplica el criterio).Sum_range debe tener el mismo tamaño y forma que intervalo. Si no es así, el rendimiento puede verse afectado y la fórmula sumará un rango de celdas que comienza con la primera celda de sum_range pero tiene las mismas dimensiones que rango. Por ejemplo:
intervalo Rango_suma Celdas sumadas reales A1:A5 B1:B5 B1:B5 A1:A5 B1:K5 B1:B5
Ejemplos
Ejemplo 1
Copie los datos de ejemplo en la tabla siguiente y péguelos en la celda A1 de una hoja de cálculo nueva de Excel. Para que las fórmulas muestren los resultados, selecciónelas, presione F2 y luego ENTRAR. Si lo necesita, puede ajustar los anchos de la columna para ver todos los datos.
| Valor de propiedad | Comisión | Datos |
|---|---|---|
| 100.000 € | 7.000 € | 250.000 € |
| 200.000 € | 14.000 € | |
| 300.000 € | 21.000 € | |
| 400.000 € | 28.000 € | |
| Fórmula | Descripción | Resultado |
| =SUMAR.SI(A2:A5;”>160000″;B2:B5) | Suma las comisiones de los valores de propiedad superiores a 160.000 €. | 63.000 € |
| =SUMAR.SI(A2:A5;”>160000″) | Suma los valores de propiedad superiores a 160.000 €. | 900.000 € |
| =SUMAR.SI(A2:A5;300000;B2:B5) | Suma las comisiones de los valores de propiedad igual a 300.000 €. | 21.000 € |
| =SUMAR.SI(A2:A5;”>” & C2;B2:B5) | Suma las comisiones de los valores de propiedad superiores al valor en C2. | 49.000 € |
Ejemplo 2
Copie los datos de ejemplo en la tabla siguiente y péguelos en la celda A1 de una hoja de cálculo nueva de Excel. Para que las fórmulas muestren los resultados, selecciónelas, presione F2 y luego ENTRAR. Si lo necesita, puede ajustar los anchos de la columna para ver todos los datos.
| Categoría | Alimento | Ventas |
|---|---|---|
| Verdura | Tomates | 2.300 € |
| Verdura | Apio | 5.500 € |
| Fruta | Naranjas | 800 € |
| Mantequilla | 400 € | |
| Verdura | Zanahorias | 4.200 € |
| Fruta | Manzanas | 1.200 € |
| Fórmula | Descripción | Resultado |
| =SUMAR.SI(A2:A7;”Frutas”;C2:C7) | Suma de las ventas de todos los alimentos en la categoría “Frutas”. | 2000 € |
| =SUMAR.SI(A2:A7;”Verduras”;C2:C7) | Suma de las ventas de todos los alimentos en la categoría “Verduras”. | 12.000 € |
| =SUMAR.SI(B2:B7;”*s”;C2:C7) | Suma de las ventas de todos los alimentos que terminan en “s” (Tomates, Naranjas y Manzanas). | 4.300 € |
| =SUMAR.SI(A2:A7;””;C2:C7) | Suma de las ventas de todos los alimentos que no tienen una categoría especificada. | 400 € |
| Descargar archivos para realizar trabajos prácticos sobre los temas abordados | |||
| ARCHIVOS SIN HACER | ARCHIVOS HECHOS | ||
 |
CONTAR.SI_Y_SUMAR.SI _SIN_HACER | |
CONTAR.SI_Y_SUMAR.SI HECHO |
 |
GUIA PRÁCTICA | ||
